Bevor Kernel-Update zuerst diese Variablen anpassen:
IP Addressen sind jeweils dem eigenen Netzwerk zufolge zu vergeben:

setenv  mem_info 'mem=96M coprocessor_mem=2M@04000000,2M@042000000 bigphysarea=4000'
setenv console_info 'console=ttyAS0,115200'
setenv gatewayip '192.168.1.1'
setenv serverip '192.168.1.2'
setenv ipaddr '192.168.1.10'
setenv netmask '255.255.255.0'
saveenv


Für kernel update:

setenv ker_size '1e0000'
setenv ker_endsec '17'
setenv burn_uimage 'tftp 84000000 uImage; protect off 1:3-$ker_endsec; erase 1:3-$ker_endsec; cp.b 84000000 a0060000 $ker_size'
saveenv

Dann Kernel Updaten mit folgendem Befehl in U-Boot:

run burn_uimage

Nach Kernel-Update weitere Variablen anpassen:

setenv net_info 'ip=$ipaddr:$serverip:$gatewayip:$netmask:$hostname:eth0:off'
setenv ethinit 'nwhwconf=device:eth0,hwaddr'
setenv bootargs_disk_fixed 'setenv bootargs $mem_info $console_info root=/dev/sda2 rw $ethinit $net_info'
setenv bootargs_disk_dhcp 'setenv bootargs $mem_info $console_info root=/dev/sda2 rw $ethinit ip=::::$hostname:eth0:dhcp'
setenv  bootcmd_disk_fixed 'run bootargs_disk_fixed; bootm a0060000'
setenv  bootcmd_disk_dhcp 'run bootargs_disk_dhcp; bootm a0060000'
saveenv

für das starten eines Systems über nfs: (bei Variable nfsdir das verzeichnis verwenden worauf der nfs-server verweist)
Pfad zum Verzeichnis des nfs-servers kann aus der Datei /etc/exports übernommen werden.

setenv nfsdir '/home/sh4-target'
setenv bootargs_nfs_fixed 'setenv bootargs $mem_info $console_info root=/dev/nfs nfsroot=$serverip:$nfsdir,rsize=4096,wsize=8192,tcp $ethinit $net_info'
setenv bootcmd_nfs_fixed 'run bootargs_nfs_fixed; bootm a0060000'
saveenv

Ganz zum Schluß nur noch die Variable setzen für "bootcmd" mit der man das system starten möchte in unserem Fall per hdd mit fester IP.
( es kann auch ein anderes benutzt werden das dann z.B. so aussieht "setenv bootcmd 'run bootcmd_nfs_fixed'" )


setenv bootcmd 'run bootcmd_disk_fixed'
saveenv


Ist alles mit saveenv abgespeichert kann mit dem Befehl "reset" in der U-Boot Shell neu gebootet werden.